SuperCollider CLASSES
UGens>Generators>Chaotic

# LatoocarfianL

Latoocarfian chaotic generator
Source: /Applications/SuperCollider.app/Contents/Resources/SCClassLibrary/Common/Audio/Chaos.sc
Inherits from: LatoocarfianN : ChaosGen : UGen : AbstractFunction : Object
See also: LatoocarfianC, LatoocarfianN

## Description

A linear-interpolating sound generator based on a function given in Clifford Pickover's book Chaos In Wonderland, pg 26. The function is:

            x(n+1) = sin(b * y(n)) + c * sin(b * x(n))
            y(n+1) = sin(a * x(n)) + d * sin(a * y(n))

According to Pickover, parameters `a` and `b` should be in the range from -3 to +3, and parameters `c` and `d` should be in the range from 0.5 to 1.5. The function can, depending on the parameters given, give continuous chaotic output, converge to a single value (silence) or oscillate in a cycle (tone).

sclang code translation:

    (
    var a = 1, b = 3, c = 0.5, d = 0.5, xi = 0.5, yi = 0.5, size = 64;
    plot(size.collect { var x = xi;
    xi = sin(b * yi) + (c * sin(b * xi));
    yi = sin(a * x) + (d * sin(a * yi));
    xi
    });
    )

NOTE: This UGen is experimental and not optimized currently, so is rather hoggish of CPU.

## Class Methods

### *ar (freq: 22050, a: 1, b: 3, c: 0.5, d: 0.5, xi: 0.5, yi: 0.5, mul: 1, add: 0)

From superclass: LatoocarfianN

#### Arguments:

freq | Iteration frequency in Hertz
a | Equation variable
b | Equation variable
c | Equation variable
d | Equation variable
xi | Initial value of x
yi | Initial value of y

### Inherited class methods

## Instance Methods

### Inherited instance methods

## Examples

    // default initial params
    { LatoocarfianL.ar(MouseX.kr(20, SampleRate.ir)) * 0.2 }.play(s);

    // randomly modulate all params
    (
    { LatoocarfianL.ar(
        SampleRate.ir/4,
        LFNoise2.kr(2,1.5,1.5),
        LFNoise2.kr(2,1.5,1.5),
        LFNoise2.kr(2,0.5,1.5),
        LFNoise2.kr(2,0.5,1.5)
    ) * 0.2 }.play(s);
    )

    (
    { LatoocarfianL.ar(
        SampleRate.ir/4,
        [LFDNoise0,LFClipNoise,LFDNoise1,LFDNoise3,
            LFNoise0,LFNoise1,LFNoise2].choose.kr(rrand(2,20),rrand(2,20)*0.1,rrand(2,20)*0.2),
            [LFDNoise0,LFClipNoise,LFDNoise1,LFDNoise3,
            LFNoise0,LFNoise1,LFNoise2].choose.kr(rrand(2,20),rrand(2,20)*0.1,rrand(2,20)*0.2),
            [LFDNoise0,LFClipNoise,LFDNoise1,LFDNoise3,
            LFNoise0,LFNoise1,LFNoise2].choose.kr(rrand(2,20),rrand(2,20)*0.1,rrand(2,20)*0.2),
            [LFDNoise0,LFClipNoise,LFDNoise1,LFDNoise3,
            LFNoise0,LFNoise1,LFNoise2].choose.kr(rrand(2,20),rrand(2,20)*0.1,rrand(2,20)*0.2)
    ) * 0.2 !2}.play;
    )

helpfile source: /Applications/SuperCollider.app/Contents/Resources/HelpSource/Classes/LatoocarfianL.schelp
link::Classes/LatoocarfianL::
sc version: 3.8.0